Grouping stuff

terminal/fish/functions/man.fish

@@ -0,0 +1,40 @@
+function man --description "Format and display the on-line manual pages"
+    # Work around the "builtin" manpage that everything symlinks to,
+    # by prepending our fish datadir to man. This also ensures that man gives fish's
+    # man pages priority, without having to put fish's bin directories first in $PATH
+
+    # My changes (Thomas Lovén)
+    # Add color to the man pager
+    #
+    # blink
+    set -lx LESS_TERMCAP_mb (set_color -o red)
+    # bold
+    set -lx LESS_TERMCAP_md (set_color -o purple)
+    set -lx LESS_TERMCAP_me (set_color normal)
+    # standout
+    set -lx LESS_TERMCAP_so (set_color -b blue) (set_color yellow)
+    set -lx LESS_TERMCAP_se (set_color normal)
+    # underline
+    set -lx LESS_TERMCAP_us (set_color -u green)
+    set -lx LESS_TERMCAP_ue (set_color normal)
+
+    set -l manpath
+    if set -q MANPATH
+        set manpath $MANPATH
+    else if command -qs manpath
+        set manpath (command manpath)
+    end
+    # Notice local exported copy of the variable.
+    set -lx MANPATH $manpath
+
+    set -l fish_manpath (dirname $__fish_datadir)/fish/man
+    if test -d "$fish_manpath" -a -n "$MANPATH"
+        set MANPATH $fish_manpath:$MANPATH
+        # Invoke man with this manpath, and we're done.
+        command man $argv
+        return
+    end
+
+    # If fish's man pages could not be found, just invoke man normally
+    command man $argv
+end